build_csr_from_coo Subroutine

    subroutine build_csr_from_coo(self)
        implicit none
        class(type_node_adjacency), intent(inout) :: self
        integer(int32) :: i

        if (self%nnz == 0) then
            if (self%num_nodes > 0) then
                call allocate_array(self%ptr, self%num_nodes + 1)
                self%ptr = 1
            end if
            call allocate_array(self%ind, 0)
            return
        end if

        ! COOデータはcreate_unique_cooによって行でソート済み
        call allocate_array(self%ptr, self%num_nodes + 1)
        call allocate_array(self%ind, self%nnz)
        self%ind = self%col ! col配列をindにコピー
        self%ptr = 0

        ! 1. 各行の非ゼロ要素数を数える (次数を計算)
        do i = 1, self%nnz
            self%ptr(self%row(i) + 1) = self%ptr(self%row(i) + 1) + 1
        end do

        ! 2. 次数の累積和からptr配列を構築
        do i = 1, self%num_nodes
            self%ptr(i + 1) = self%ptr(i) + self%ptr(i + 1)
        end do

        ! Fortranは1-based indexなので、全体に1を加算
        self%ptr = self%ptr + 1

        ! 3. 各行の列インデックスをソートする
        do i = 1, self%num_nodes
            if (self%ptr(i + 1) > self%ptr(i)) then
                call sort(self%ind(self%ptr(i):self%ptr(i + 1) - 1))
            end if
        end do
    end subroutine build_csr_from_coo